#include <map>
#include <deque>
#include <vector>
#include <fstream>
#include <iostream>
#include <algorithm>
#include <sys/time.h>

#ifndef __CUDACC__
#define XCPU
#elif __CUDA_ARCH__ >= 120
#define USMA
#endif

#ifdef XCPU
#include <cmath>
#include <cstring>
#endif

using namespace std;

namespace xppc{
#include "ini.cxx"
#include "pro.cu"

  void initialize(){ m.set(); }
#ifdef XLIB
  void igeo(float enh){ m.geo(); d.eff*=enh; }
#endif

  dats *e;  // pointer to a copy of "d" on device
  unsigned int pmax, pmxo, pn;

  int nblk, nthr, ntot;
  void ini(){
    ntot=nblk*nthr;
    pmax=ntot*NPHO;
    d.hnum=pmax/HQUO;
    pmxo=pmax/OVER;
    pn=0;
  }

#ifdef XCPU
  void ini(int type){
    ini();

    {
      d.hits = q.hits = new hit[d.hnum];
      if(type==0) d.pz = q.pz = new photon[pmxo];
    }

    {
      d.z=&z; e=&d; oms=q.oms;
    }

    {
      unsigned int size=d.rsize, need=seed+1;
      if(size<need) cerr<<"Error: not enough multipliers: asked for "<<seed<<"-th out of "<<size<<"!"<<endl;
    }
  }

  void fin(){
    if(d.type==0) delete d.pz;
    delete d.hits;
  }
#else
  float deviceTime=0, threadMin=0, threadMax=0;
  cudaDeviceProp prop;
  cudaStream_t stream;
  cudaEvent_t evt1, evt2;

  void checkError(cudaError result){
    if(result!=cudaSuccess){
      cerr<<"CUDA Error: "<<cudaGetErrorString(result)<<endl;
      exit(2);
    }
  }

  void ini(int type){
    ini();

    {
      char * bmp=getenv("BADMP");
      d.blockIdx=-1, d.gridDim=nblk;
      if(bmp!=NULL) if(*bmp!=0){
	d.blockIdx=atoi(bmp), d.gridDim--;
	cerr<<"Not using MP #"<<d.blockIdx<<endl;
      }
    }

    {
      checkError(cudaStreamCreate(&stream));
      checkError(cudaEventCreateWithFlags(&evt1, cudaEventBlockingSync));
      checkError(cudaEventCreateWithFlags(&evt2, cudaEventBlockingSync));
    }

    {
      unsigned int size=d.rsize;
      if(size<ntot) cerr<<"Error: not enough multipliers: only have "<<size<<" (need "<<ntot<<")!"<<endl;
      else d.rsize=ntot;
    }

    int tot=0, cnt=0;

    {
      unsigned int size=sizeof(datz); tot+=size;
      checkError(cudaMalloc((void**) &d.z, size));
      checkError(cudaMemcpy(d.z, &z, size, cudaMemcpyHostToDevice));
    }

    {
      unsigned int size=d.hnum*sizeof(hit); tot+=size;
      checkError(cudaMalloc((void**) &d.hits, size));
      checkError(cudaMallocHost((void**) &q.hits, size));
    }

    if(d.type==0){
      unsigned int size=pmxo*sizeof(photon); tot+=size;
      checkError(cudaMalloc((void**) &d.pz, size));
      checkError(cudaMallocHost((void**) &q.pz, size));
    }

    {
      unsigned int size=d.gsize*sizeof(DOM); cnt+=size;
      checkError(cudaMemcpyToSymbol(oms, q.oms, size));
    }

    {
      unsigned int size=sizeof(dats); tot+=size;
      checkError(cudaMalloc((void**) &e, size));
      checkError(cudaMemcpy(e, &d, size, cudaMemcpyHostToDevice));
    }

    cerr<<"Total GPU memory usage: "<<tot<<"  const: "<<cnt<<endl;
  }

  void fin(){
    checkError(cudaFree(d.z));
    checkError(cudaFree(d.hits));
    checkError(cudaFreeHost(q.hits));
    if(d.type==0){
      checkError(cudaFree(d.pz));
      checkError(cudaFreeHost(q.pz));
    }
    checkError(cudaFree(e));
    checkError(cudaEventDestroy(evt1));
    checkError(cudaEventDestroy(evt2));
    checkError(cudaStreamDestroy(stream));
  }

  void listDevices(){
    int deviceCount, driver, runtime;
    cudaGetDeviceCount(&deviceCount);
    cudaDriverGetVersion(&driver);
    cudaRuntimeGetVersion(&runtime);
    fprintf(stderr, "Found %d devices, driver %d, runtime %d\n", deviceCount, driver, runtime);
    for(int device=0; device<deviceCount; ++device){
      cudaGetDeviceProperties(&prop, device);
      fprintf(stderr, "%d(%d.%d): %s %g GHz G(%lu) S(%lu) C(%lu) R(%d) W(%d)\n"
	      "\tl%d o%d c%d h%d i%d m%d a%lu M(%lu) T(%d: %d,%d,%d) G(%d,%d,%d)\n",
	      device, prop.major, prop.minor, prop.name, prop.clockRate/1.e6,
	      (unsigned long)prop.totalGlobalMem, (unsigned long)prop.sharedMemPerBlock,
	      (unsigned long)prop.totalConstMem, prop.regsPerBlock, prop.warpSize,
	      prop.kernelExecTimeoutEnabled, prop.deviceOverlap, prop.computeMode,
	      prop.canMapHostMemory, prop.integrated, prop.multiProcessorCount,
	      (unsigned long)prop.textureAlignment,
	      (unsigned long)prop.memPitch, prop.maxThreadsPerBlock,
	      prop.maxThreadsDim[0], prop.maxThreadsDim[1], prop.maxThreadsDim[2],
	      prop.maxGridSize[0], prop.maxGridSize[1], prop.maxGridSize[2]);
    }
    fprintf(stderr, "\n");
  }

  static unsigned int old=0;
#endif

#include "f2k.cxx"

  void kernel(unsigned int num){
#ifdef XCPU
    unsigned int & old = num;
#endif
    if(old>0){
#ifdef XCPU
      d.hidx=0;
      for(d.blockIdx=0, d.gridDim=nblk, blockDim.x=nthr; d.blockIdx<d.gridDim; d.blockIdx++)
	for(threadIdx.x=0; threadIdx.x<blockDim.x; threadIdx.x++) propagate(e, num);
#else
      checkError(cudaStreamSynchronize(stream));
      checkError(cudaMemcpy(&d, e, 7*sizeof(int), cudaMemcpyDeviceToHost));

      float dt;
      checkError(cudaEventElapsedTime(&dt, evt1, evt2)); deviceTime+=dt;

      if(d.ab>0){
	cerr<<"Error: TOT was a nan or an inf "<<d.ab<<" times! Bad MP";
	for(int i=0; i<min(d.ab, 4); i++) cerr<<" #"<<d.bmp[i]; cerr<<endl;
      }
      if(d.mp!=d.gridDim){ cerr<<"Error: did not encounter MP #"<<d.blockIdx<<endl; exit(4); }
      if(threadMax!=-1){
	if((unsigned long long)(dt*prop.clockRate)<0x100000000ULL){
	  threadMin+=d.tn/(float)prop.clockRate;
	  threadMax+=d.tx/(float)prop.clockRate;
	}
	else threadMin=-1, threadMax=-1;
      }
#endif

      cerr<<"photons: "<<old<<"  hits: "<<d.hidx<<endl;
      if(d.hidx>=d.hnum){ d.hidx=d.hnum; cerr<<"Error: data buffer overflow occurred!"<<endl; }

#ifndef XCPU
      unsigned int size=d.hidx*sizeof(hit);
      checkError(cudaMemcpyAsync(q.hits, d.hits, size, cudaMemcpyDeviceToHost, stream));
#endif
    }

#ifndef XCPU
    checkError(cudaStreamSynchronize(stream));
    if(num>0){
      checkError(cudaEventRecord(evt1, stream));

      propagate<<< 1, 1, 0, stream >>>(e, 0);
      checkError(cudaGetLastError());

      propagate<<< nblk, nthr, 0, stream >>>(e, num);
      checkError(cudaGetLastError());

      checkError(cudaEventRecord(evt2, stream));
    }
#endif

    if(old>0) print();
#ifndef XCPU
    old=num;
#endif
  }

  void flini(int str, int dom){
    int type=1;
    float r[3]={0, 0, 0};

    if(str<0){ type=2; str=-str; }
    if(str==0) switch(dom){
      case 1: type=3; r[0]=544.07; r[1]=55.89; r[2]=136.86; break;
      case 2: type=4; r[0]=11.87; r[1]=179.19; r[2]=-205.64; break;
    }
    else for(int n=0; n<d.gsize; n++) if(q.names[n].str==str && q.names[n].dom==dom){
#ifdef OFLA
      d.fla=n;
#endif
      for(int m=0; m<3; m++) r[m]=q.oms[n].r[m]; break;
    }

    d.type=type; for(int m=0; m<3; m++) d.r[m]=r[m];
    ini(type);
  }

  void flone(unsigned long long num){
    for(long long i=num; i>0; i-=pmax) kernel(min(i, (long long) pmax));
#ifndef XCPU
    kernel(0);
#endif
  }

  void flasher(int str, int dom, unsigned long long num, int itr){
    flini(str, dom);

    for(int j=0; j<max(1, itr); j++){
      flone(num);
      if(itr>0) printf("\n");
    }

    fin();
  }

  void output(){
#ifndef XCPU
    {
      if(old>0) checkError(cudaStreamSynchronize(stream));
      unsigned int size=pn*sizeof(photon);
      checkError(cudaMemcpyAsync(d.pz, q.pz, size, cudaMemcpyHostToDevice, stream));
    }
#endif

    kernel(pn*OVER); pn=0;

#ifndef XCPU
    flnd=flne;
#endif
  }

#ifdef XCPU
  void start(){}
  void stop(){}
  void choose(int device){
    sv+=device;
    seed=device;
    nblk=NBLK, nthr=NTHR;
  }
  void listDevices(){}
#else
  void start(){
    cudaSetDeviceFlags(cudaDeviceBlockingSync);
  }

  void stop(){
    fprintf(stderr, "\nDevice time: %2.1f (in-kernel: %2.1f...%2.1f) [ms]\n", deviceTime, threadMin, threadMax);
    checkError(cudaThreadExit());
  }

  void choose(int device){
    sv+=device;
    checkError(cudaSetDevice(device));
    checkError(cudaGetDeviceProperties(&prop, device));

#if CUDART_VERSION >= 3000
    checkError(cudaFuncSetCacheConfig(propagate, cudaFuncCachePreferL1));
#endif

    cudaFuncAttributes attr;
    checkError(cudaFuncGetAttributes (&attr, propagate));

    nblk=prop.multiProcessorCount, nthr=attr.maxThreadsPerBlock;
    cerr<<"Running on "<<nblk<<" MPs x "<<nthr<<" threads"<<endl;

    fprintf(stderr, "Kernel uses: l=%lu r=%d s=%lu c=%lu\n", (unsigned long)attr.localSizeBytes,
	    attr.numRegs, (unsigned long)attr.sharedSizeBytes, (unsigned long)attr.constSizeBytes);
  }
#endif
}

#ifndef XLIB
using namespace xppc;

int main(int arg_c, char *arg_a[]){
  start();
  if(arg_c<=1){
    listDevices();
    fprintf(stderr, "Use: %s [device] (f2k muons)\n"
	    "     %s [str] [om] [num] [device] (flasher)\n", arg_a[0], arg_a[0]);
  }
  else if(0==strcmp(arg_a[1], "-")){
    initialize();
    ices & w = z.w[WNUM/2];
    cerr<<"For wavelength="<<w.wvl<<" [nm]  np="<<(1/w.coschr)<<"  cm="<<1/w.ocm<<" [m/ns]"<<endl;
#ifdef TILT
    float4 r;
    r.w=0;
    if(arg_c==4){
      r.x=atof(arg_a[2]);
      r.y=atof(arg_a[3]);
    }
    else r.x=0, r.y=0;
#endif
    for(int i=0; i<d.size; i++){
      float z=d.hmin+d.dh*i;
#ifdef TILT
      r.z=z; for(int j=0; j<10; j++) r.z=z+zshift(d, r); z=r.z;
#endif
      cout<<z<<" "<<w.z[i].abs<<" "<<w.z[i].sca*(1-d.g)<<endl;
    }
  }
  else if(arg_c<=2){
    int device=0;
    if(arg_c>1) device=atoi(arg_a[1]);
    initialize();
    choose(device);
    fprintf(stderr, "Processing f2k muons from stdin on device %d\n", device);
    f2k();
  }
  else{
    int str=0, dom=0, device=0, itr=0;
    unsigned long long num=1000000ULL;

    if(arg_c>1) str=atoi(arg_a[1]);
    if(arg_c>2) dom=atoi(arg_a[2]);
    if(arg_c>3){
      num=(unsigned long long) atof(arg_a[3]);
      char * sub = strchr(arg_a[3], '*');
      if(sub!=NULL) itr=(int) atof(++sub);
    }
    if(arg_c>4) device=atoi(arg_a[4]);
    initialize();
    choose(device);
    fprintf(stderr, "Running flasher simulation on device %d\n", device);
    flasher(str, dom, (unsigned long long)llroundf(num*(long double)d.eff), itr);
  }

  stop();
}
#endif